# Contributor: Toby Vincent <tobyv13@gmail.com>
# Maintainer: Toby Vincent <tobyv13@gmail.com>
pkgname=projectr-git
pkgver=0.3.2.r0.g4f6865b
pkgrel=1
pkgdesc="A contextual, MRU sorted, project finder."
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="https://git.sr.ht/~tobyvin/projectr"
license=('MIT')
makedepends=('cargo' 'git')
optdepends=('tmux-projectr: fzf-tmux support')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+https://git.sr.ht/~tobyvin/projectr")
b2sums=('SKIP')

pkgver() {
	cd "$srcdir/${pkgname%-git}"

	printf "%s" "$(git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g')"
}

prepare() {
	cd "$srcdir/${pkgname%-git}"

	export RUSTUP_TOOLCHAIN=stable
	cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
	cd "$srcdir/${pkgname%-git}"

	export RUSTUP_TOOLCHAIN=stable
	export CARGO_TARGET_DIR=target
	cargo build --frozen --release --all-features
	cargo xtask outdir >out_dir
}

check() {
	cd "$srcdir/${pkgname%-git}"

	export RUSTUP_TOOLCHAIN=stable
	cargo test --frozen --all-features
}

package() {
	cd "$srcdir/${pkgname%-git}"

	local OUT_DIR=$(<out_dir)

	install -Dm755 "target/release/${pkgname%-git}" "$pkgdir/usr/bin/${pkgname%-git}"

	install -Dm644 "$OUT_DIR/completion/_${pkgname%-git}" "$pkgdir/usr/share/zsh/site-functions/_${pkgname%-git}"
	install -Dm644 "$OUT_DIR/completion/${pkgname%-git}" "$pkgdir/usr/share/bash-completion/completions/${pkgname%-git}"
	install -Dm644 "$OUT_DIR/completion/${pkgname%-git}.fish" "$pkgdir/usr/share/fish/vendor_completions.d/${pkgname%-git}.fish"

	install -Dm644 "$OUT_DIR/man/${pkgname%-git}.1" "$pkgdir/usr/share/man/man1/${pkgname%-git}.1"

	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${pkgname%-git}/LICENSE"

	install -Dm644 README.md "$pkgdir/usr/share/doc/${pkgname%-git}/README.md"
	install -Dm644 CHANGELOG.md "$pkgdir/usr/share/doc/${pkgname%-git}/CHANGELOG.md"
}