chore: add various archlinux PKGBUILDs

1 files changed, 51 insertions, 0 deletions

diff --git a/pkg/archlinux/projectr-git/PKGBUILD b/pkg/archlinux/projectr-git/PKGBUILD
new file mode 100644
index 0000000..0cf3dd4
--- /dev/null
+++ b/pkg/archlinux/projectr-git/PKGBUILD
@@ -0,0 +1,51 @@
+# Contributor: Toby Vincent <tobyv13@gmail.com>
+# Maintainer: Toby Vincent <tobyv13@gmail.com>
+pkgname=projectr-git
+pkgver=0.3.2.r0.g4f6865b
+pkgrel=1
+pkgdesc="A contextual, MRU sorted, project finder."
+arch=('i686' 'x86_64' 'armv6h' 'armv7h')
+url="https://git.sr.ht/~tobyvin/projectr"
+license=('MIT')
+makedepends=('cargo' 'git')
+optdepends=('fzf: tmux-projectr support' 'tmux: tmux-projectr support')
+provides=('projectr' 'tmux-projectr')
+conflicts=('projectr' 'tmux-projectr')
+source=("$pkgname::git+https://git.sr.ht/~tobyvin/projectr")
+b2sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+    cd "$pkgname"
+
+	export RUSTUP_TOOLCHAIN=stable
+	cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+    cd "$pkgname"
+
+	export RUSTUP_TOOLCHAIN=stable
+	export CARGO_TARGET_DIR=target
+	cargo build --frozen --release --all-features
+}
+
+check() {
+    cd "$pkgname"
+
+	export RUSTUP_TOOLCHAIN=stable
+	cargo test --frozen --all-features
+}
+
+package() {
+	cd "$pkgname"
+
+	install -Dm755 "target/release/projectr" "$pkgdir/usr/bin/projectr"
+	install -Dm644 "README.md" "$pkgdir/usr/share/doc/projectr/README.md"
+	install -Dm644 "LICENSE" "$pkgdir/usr/share/doc/projectr/LICENSE"
+	install -Dm644 "CHANGELOG.md" "$pkgdir/usr/share/doc/projectr/CHANGELOG.md"
+}