blob: 23a21dfd69b5da5eb50ce5c7625ac3eb6fbc2d11 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Contributor: Toby Vincent <tobyv13@gmail.com>
# Maintainer: Toby Vincent <tobyv13@gmail.com>
pkgname=projectr
pkgver=0.4.1
pkgrel=1
pkgdesc="A contextual, MRU sorted, project finder."
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="https://git.sr.ht/~tobyvin/projectr"
license=('MIT')
makedepends=('cargo')
optdepends=('tmux-projectr: fzf-tmux support')
source=("$pkgname-$pkgver.tar.gz::https://static.crates.io/crates/$pkgname/$pkgname-$pkgver.crate")
b2sums=('53241e79e55a2957b7956725e4da288abda9e94d4409399782c50ed7418bc1c5445b8b54b6e5276dd9775ab0e14af19e192200d7b984ca3da3a1b48bf2de4791')
prepare() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
cargo xtask out-dir >out_dir
}
check() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
}
package() {
cd "$pkgname-$pkgver"
local OUT_DIR=$(<out_dir)
install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
install -Dm644 "$OUT_DIR/completion/_$pkgname" "$pkgdir/usr/share/zsh/site-functions/_$pkgname"
install -Dm644 "$OUT_DIR/completion/$pkgname" "$pkgdir/usr/share/bash-completion/completions/$pkgname"
install -Dm644 "$OUT_DIR/completion/$pkgname.fish" "$pkgdir/usr/share/fish/vendor_completions.d/$pkgname.fish"
install -Dm644 "$OUT_DIR/man/$pkgname.1" "$pkgdir/usr/share/man/man1/$pkgname.1"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm644 CHANGELOG.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"
}
|
